Algorithmus zur grafischen Darstellung einer Mandelbrotmenge

Folgendes Beispiel ist der Code eines VB.Net-Programms. Es muss eine PictureBox mit Namen picGrafik auf ein Formular platziert werden. Danach wird die untenstehende Prozedur aufgerufen und es erscheint eine Mandelbrotmenge in der PictureBox.

   Sub ZeichneGrafik()
      ' Diese Sub erzeugt die grafische Darstellung einer Mandelbrotmenge (Apfelmännchen)
      ' © 2002, K. F. Meis
      Dim bitmap As New Bitmap(picGrafik.Width + 1, picGrafik.Height + 1, _
                               System.Drawing.Imaging.PixelFormat.Format24bppRgb)
      Dim x, y As Integer '          Laufvariablen
      Dim x1, y1, x2, y2 As Double ' Mandelbrot-Ausschnitts-Koordinaten
      Dim depth As Integer '         Berechnungstiefe
      Dim d As Integer '             Laufvariable für Tiefe
      Dim dx, dy As Double '         Schrittweite pro Pixel
      Dim px, py As Double '         aktuelle Weltkoordinate
      Dim u, v As Double '           Berechnungsvariablen
      Dim ax, ay As Double '         Berechnungsvariablen
      Dim c(255) As Color
      ' 255 Zufallsfarben erzeugen
      For x = 0 To 255
         c(x) = Color.FromArgb(RGB(255 * Rnd(1), 255 * Rnd(1), 255 * Rnd(1)))
      Next
      ' Ausschnitt der Grafik
      x1 = -2.0
      y1 = -1.6
      x2 = 1
      y2 = 1.6
      depth = 140 ' maximal 255 (sonst mehr Zufallsfarben erzeugen!)
      dx = (x2 - x1) / picGrafik.Width
      dy = (y2 - y1) / picGrafik.Height
      ' Erzeugung des Bitmap
      For y = 0 To picGrafik.Height
         For x = 0 To picGrafik.Width
            px = x1 + x * dx
            py = y1 + y * dy
            d = 0
            ax = 0
            ay = 0
            Do
               u = ax * ax - ay * ay + px
               v = 2 * ax * ay + py
               ax = u
               ay = v
               d += 1
            Loop Until ax * ax + ay * ay > 8 Or d = depth
            bitmap.SetPixel(x, y, c(d))
         Next
         Me.Text = "Mandelbrot - Line: " & y.ToString
      Next
      ' Fertiges Bitmap darstellen
      picGrafik.CreateGraphics.DrawImage(bitmap, 0, 0, picGrafik.Width, picGrafik.Height)
   End Sub

Als Ergebnis dieses Programms kommt dann eine Grafik wie die folgende heraus:

Wenngleich diese Grafik ein hohes Maß an virtueller Komplexität aufweist, so enthält sie doch keine Information, denn sie ist durch einen einfachen Algorithmus zu erzeugen. Algorithmen können aber keine wirklich komplexe, semantische Information erzeugen.